;Alan's Truth or Dare script
;Place this script in the 'spinner' in the center of the room.
;Place 10 door pictures of the spinner pointing to each position in this door.
ON ENTER
{
	spinOK GLOBAL
	0 spinOK =
	"\x0dHi " USERNAME & ".  Pick a spot to sit." LOCALMSG 
	"When it is your turn, type 'spin' or click on the pointer." & LOCALMSG
}

ON INCHAT
{
	{ 0 ME SETSPOTSTATELOCAL
	} CHATSTR ";###Reset###" == IF
;
	{ "$1" GREPSUB ATOI num =
	0 sp =
		{
			{ 0 ME SETSPOTSTATELOCAL
			} { ME GETSPOTSTATE 1 + ME SETSPOTSTATELOCAL } ME GETSPOTSTATE 10 > IFELSE
		sp++
		} { sp num < } WHILE
		{ "The arrow points to number " ME GETSPOTSTATE 1 + ITOA & SAY } WHOME WHOCHAT == IF
 } CHATSTR "^;###([0-9]*)###$" GREPSTR IF
}

ON OUTCHAT
{
	{ ME SELECT
	"" CHATSTR =
	} CHATSTR "spin" == IF

;defeat cheaters
	{ "No cheating!  ;-)" LOCALMSG
	"" CHATSTR =
	} CHATSTR ";###" SUBSTR IF

;if you want to cheat
	{ "$1" GREPSUB ATOI 1 - ME GETSPOTSTATE - 24 + count =
	";###" count ITOA & "###" & SAY
	USERNAME " is spinning." & ROOMMSG
	"" CHATSTR =
	} CHATSTR "^stopon ([0-9]*)" GREPSTR IF
}

ON SELECT
{
	spinOK GLOBAL
		{ 1 spinOK =
		";###Reset###" SAY
		USERNAME " is joining the game!" & ROOMMSG
		} spinOK NOT IF
	USERNAME " is spinning." & ROOMMSG
	";###" 24 RANDOM 12 + ITOA & "###" & SAY
}