;Alan's refresh control script
;Place this script in the room from which you want to start the prop refresh cycle.
;DO NOT PUT THIS SCRIPT IN EVERY ROOM YOU WANT TO REFRESH.
ON OUTCHAT
{
	refresh GLOBAL
	refresh_time GLOBAL
	refresh_startroom GLOBAL
	roomarraydef GLOBAL
	roomarrayindex GLOBAL
	cmd GLOBAL
	mainscript GLOBAL
	{ [
;*****************************************************************************
;list the room numbers of the rooms that have prop generators to be refreshed
;in form 123 456 789
	91 95
;*****************************************************************************
	] roomarray =
	roomarray LENGTH nbrrooms = } roomarraydef DEF
;*****************************************************************************
;Set the refresh time in seconds (time between prop changes)
	5 refresh_time =
;*****************************************************************************
;
	ROOMID refresh_startroom =
	{ "List the room numbers of the prop rooms you want to refresh in the 'start' script where indicated." LOCALMSG
	"Say 'startrefresh' to start the refresh cycle. When finished you will be returned to this room." LOCALMSG
	"Say 'stoprefresh' to stop the refresh cycle and stay in the room you're currently in." LOCALMSG
	"Say 'resumerefresh' to resume the refresh if you have stopped it." LOCALMSG
	"You must be an Owner or Operator to use these commands." LOCALMSG
	} CHATSTR "help" ==
	  ISWIZARD AND IF
;
	{ 1 refresh =
	0 roomarrayindex =
	"" CHATSTR =
	roomarraydef EXEC
	roomarray 0 GET firstroom =
		{ "refresh" cmd =
		0 mainscript SETALARM } { firstroom GOTOROOM
		} firstroom ROOMID == IFELSE
	} CHATSTR "startrefresh" ==
	  ISWIZARD AND IF
}