;Alan's prop edit script.
;Place the following script in the color background door:
ON ENTER
{
	colordoor GLOBAL
	ME colordoor =
	"Select a color button to change the background color." LOCALMSG
}




;Place the following script in the color bar door:
;Alan's Mouseover sript #2
;Create a horizontally shaped door comprised of some number of equally wide segments.
;When the mouse is 'clicked' over different portions of this door
;it will change the door picture of the another door.
ON SELECT
{
	colordoor GLOBAL
;************************************************************************
;Define the shape of the door, how many equi-shaped sections there are.
	132 xleft =
	361 xright =
	67 ytop =
	99 ybottom =
	8 sections =
;************************************************************************
	{ MOUSEPOS POP x =
	xright xleft - sections / width =
	x xleft - width / 1 + mouseover =
	mouseover colordoor SETSPOTSTATELOCAL
	} MOUSEPOS DUP ytop >= SWAP ybottom <= AND
		 SWAP DUP xleft >= SWAP xright <= AND AND IF
}




;Alan's drop-prop script
;Place the following script in the Drop Prop door:
ON SELECT
{
;************************************************************************
;Define where you want the first prop to go
	38 x =
	300 y =
;and how far apart each one will be from the last one.
	49 spacing =
;************************************************************************	
	CLEARLOOSEPROPS
;drop the props horizontally across the room
	{ x y DROPPROP
	spacing x +=
	} { TOPPROP } WHILE
}

ON LEAVE
{
	{ CLEARLOOSEPROPS } NBRROOMUSERS 2 < IF
}