;Alan's Merry-go-Round room
;Place this in a spot covering the Merry-go-Round ride area
ON ENTER
{
	stop GLOBAL
	1 stop =
	0 ME SETSPOTSTATE
	"!Hop on the merry-go-round for a ride." LOCALMSG
	"!Hop off to stop your ride." LOCALMSG
;	"Picture and music courtesy of Sweet Water Creek (213.239.130.9:8969)." LOCALMSG
;save_props - save currently worn props
	save_props GLOBAL
	{ saved_prop GLOBAL
	"[ " p =
	0 i =
		{ p i USERPROP ITOA & " " & p =
		i ++
		}	{ i NBRUSERPROPS < } WHILE
	p " ]" & saved_prop =
	} save_props DEF
;restore_props - restore saved prop
	restore_props GLOBAL
	{ saved_prop GLOBAL
		{ NAKED } { saved_prop STRTOATOM EXEC SETPROPS} "[  ]" saved_prop == IFELSE
	} restore_props DEF
}
ON OUTCHAT
{
	stop GLOBAL
;	{ 1 stop =
;	"" CHATSTR =
;	} CHATSTR "stop" == IF
	{ "@" POSX ITOA & " " & POSY ITOA & USERNAME & ":  " & CHATSTR & ROOMMSG
	"" CHATSTR =
 } stop NOT IF
}
ON SELECT
{
	stop GLOBAL
	yoffset GLOBAL
	{ save_props GLOBAL  save_props EXEC
	[
;*******put random avs below.  Enclose each set of prop IDs in square brackets*******
[ 980749276 980749290 980749301 980749311 980749328 980749342 980749353 ]
[ 976952504 976952191 976941211 976952416 976939738 976941191 976951902 976951846 ]
[ 976997759 976866617 976866526 976853930 976866460 976854533 976854781 976856263 ]
[ 976859038 976857135 976867050 976867256 976866838 976858379 976857975 976857554 ]
[ 976950212 976950086 976950506 976950439 976950968 976950429 976951075 ]
[ 976948260 976946781 976948980 976948843 976948531 976948593 976948167 976947648 ]
[ 976780626 976783905 976782260 976782059 976781994 976781929 ]
[ 976863196 976864297 976864368 976865585 976864697 976865115 976863720 976863684 ]
[ 986285020 976946275 986276133 976945941 976946052 976945042 976946342 976945528 986690825 ]
;*******end of random avs********
	] animals =
	animals LENGTH N =
	animals ME GETSPOTSTATE GET SETPROPS
	ME GETSPOTSTATE 1 + N % ME SETSPOTSTATELOCAL			;cycle up
	0 stop =
	-5 yoffset =
	1 ME SETALARM
	} stop IF
}
ON ALARM
{
	stop GLOBAL
	yoffset GLOBAL
	260 ylow =												;lowest part of ride
	320 yhigh =												;highest part of ride
	{ 20 POSY SETPOS } { 10 yoffset MOVE }  POSX 480 > IFELSE
	{ 5 yoffset = } POSY ylow < IF
	{ -5 yoffset = } POSY yhigh > IF
	{ 15 ME SETALARM } stop NOT IF
}



;place this script in a spot covering the rest of the room
;this stops the merry-go-round
ON SELECT
{
	stop GLOBAL
	{ restore_props GLOBAL  restore_props EXEC
	1 stop =
	} stop NOT IF
}
;this plays background music if you have any.
ON ENTER
{
	snd GLOBAL
	1 snd =
	"Say 'on' or 'off' to control the background music." LOCALMSG
	1 ME SETALARM
}
ON OUTCHAT
{
	snd GLOBAL
	{ 1 snd =
	1 ME SETALARM
	"" CHATSTR = } CHATSTR "on" ==
	                snd NOT AND IF
	{ 0 snd =
	"" CHATSTR = } CHATSTR "off" == IF
}
ON ALARM
{
	snd GLOBAL
	{ "merrygoround.mid" SOUND
	11400 ME SETALARM
	} snd IF
}