;Alan's Jukebox Script #3
;Written for Moonwind for Eternity
;Place the following script in a Jukebox spot
ON ENTER
{
	"@233 154 Click on the jukebox for a list of the songs in this room." LOCALMSG
;
	tunelist GLOBAL
	{
;***list your tunes here
	[ "iwannabeurunderwear.wav" "back2good.wav" "Badisbad.wav" "backintheussr.wav" "badmoonrising.wav" "HonkyTonk.wav" "Uninvited.wav" "coveroftherollingstone.wav" ] Atunearray =
	[ "BiffShinyThings.wav" "Time.wav" "carryonbybiff" "feelinlove.wav" "gmornin.wav" "hellsbells.wav" "brownsugar.wav" "paintitblack.wav" ] Btunearray =
	[ "absenceoffear.wav" "walkthisway.wav" "eres_tu.wav" "myhomesinalabama.wav" "CDlovedoesntask.wav" "bsoldtimerockandroll" "FromHereToEternity.wav" ] Ctunearray =
	[ "Afterall.wav" "AllAlongTheWatchtower.wav ""AgainstAllOdds.wav" "allornothing.wav" "FoxyLady.wav" "herecomesthesun.wav"]Dtunearray =
	[ "Amazed.wav" "ladyinred.wav" "houseoftherising.wav" "ECCocaine.wav" "candle.wav" "l3codecx.exe" ] Etunearray =
	[ ] Ftunearray =
	[ ] Gtunearray =
	[ ] Htunearray =
	[ ] Jtunearray =
	[ ] Ktunearray =
;***end of list
	[ "Atunearray" "Btunearray" "Ctunearray" "Dtunearray" "Etunearray" "Ftunearray"
	"Gtunearray" "Htunearray" "Jtunearray" "Ktunearray" ] arraynames =
	} tunelist DEF
;
	playlist GLOBAL
	{ arrayname 0 1 SUBSTRING ltr =
	1 nbr =
		{ tune =
		ltr nbr ITOA & "  " & tune & LOGMSG
		nbr ++
		} arrayname STRTOATOM EXEC FOREACH
	"" LOGMSG
	} playlist DEF
}
ON OUTCHAT
{
	{ MIDISTOP			;if Midi on a PC
	"" CHATSTR =
	} CHATSTR "ms" == IF
}
ON SELECT
{
	playlist GLOBAL
	tunelist GLOBAL tunelist EXEC
	{ DUP GLOBAL 1 SWAP SETSPOTSTATELOCAL } [ spotA spotB spotC spotD spotE spotF spotG spotH spotJ
	spot1 spot2 spot3 spot4 spot5 spot6 spot7 spot8 spot9 spot10 ] FOREACH
;
	"@233 154 Instructions and the playlist are in your log." LOCALMSG
	"Click on a letter and then a number to select a tune." LOGMSG
	"If you have not previously played the tune you will have to wait for it to download and then select it again." LOGMSG
	"PC's - enter 'ms' to stop a midi that is playing." LOGMSG
	"\x0dAvailable selections are:" LOGMSG
	{ arrayname =
		{ playlist EXEC } arrayname STRTOATOM EXEC LENGTH IF
	} arraynames FOREACH
}


;Place the following script in Letter A
;Place the letter A in the spot as the second picture (the first one should be blank).
ON ENTER
{
	spotA GLOBAL
	ME spotA =
	0 ME SETSPOTSTATELOCAL
;
	letter GLOBAL
	{ ltr =
	tunelist GLOBAL tunelist EXEC
	arrayname GLOBAL
	arraylength GLOBAL
	playlist GLOBAL
;selected letter - list tunes available
		arraynames ltr GET arrayname =
		arrayname STRTOATOM EXEC LENGTH arraylength =
			{ "\xodAvailable selections are:" LOGMSG
			playlist EXEC
			"Select a number to play one of these." LOGMSG
			} arraylength ME GETSPOTSTATE AND IF
	} letter DEF
}
ON SELECT
{
	letter GLOBAL
	0 letter EXEC
}


;Place the following script in Letter B through Letter J.
;Change spotB to spotB through spotJ.
;Change the value in the last line from 1 (spotB) through 9 (spotJ)
;Place the letters B through J in the spots as the second picture (the first one should be blank).
ON ENTER
{
	spotB GLOBAL
	ME spotB =
	0 ME SETSPOTSTATELOCAL
}
ON SELECT
{
	letter GLOBAL
	1 letter EXEC
}



;Place the following script in Number 1
;Place the number 1 in the spot as the second picture (the first one should be blank).
ON ENTER
{
	spot1 GLOBAL
	ME spot1 =
	0 ME SETSPOTSTATELOCAL
;
	arraylength GLOBAL
	0 arraylength =
	number GLOBAL
	{ nbr =
	tunelist GLOBAL tunelist EXEC
	arrayname GLOBAL
	arraylength GLOBAL
	playlist GLOBAL
;selected number
		{ arrayname STRTOATOM EXEC nbr GET tune =
		"@311 68 You have selected " tune & LOCALMSG
		tune SOUND
		;if an old client use MIDIPLAY in case it is a midi on a PC.
			{ CHATSTR MIDIPLAY } IPTVERSION NOT IF
		} nbr arraylength < ME GETSPOTSTATE AND IF
	} number DEF
}
ON SELECT
{
	number GLOBAL
	0 number EXEC
}


;Place the following script in Number 2 through Number 10
;Change spot2 to spot2 through spot10.
;Change the value in the last line from 1 (spot2) through 9 (spot10)
;Place the numbers B through J in the spots as the second picture (the first one should be blank).
ON ENTER
{
	spot2 GLOBAL
	ME spot2 =
	0 ME SETSPOTSTATELOCAL
}
ON SELECT
{
	number GLOBAL
	1 number EXEC
}