;Alan's jukebox script
ON ENTER   
{
	"Click on the jukebox for a list of the songs in this room." LOCALMSG
	"Type the name of a song to play it."  LOCALMSG
	"If you have not previously downloaded the song you will have to wait for it to download and then type the name again to play it." LOCALMSG
	"PC's - enter 'ms' to stop a midi if it is playing." LOCALMSG
	
	marray GLOBAL
	{ [
;**********************************************************************
;  List song titles here in format "name1" "name2"
	"m_cream_m"  "m_zhivago"  "theman"
;**********************************************************************
	] musicarray =
	} marray DEF
}

ON SELECT  
{
	marray GLOBAL
 	marray EXEC

	"Type one of the following names to play it:  "
		{ name =
			{ "$1" GREPSUB name = } name "(.*)[.](.*)" GREPSTR IF
		name & ", " &
		} musicarray FOREACH LOCALMSG
}
 
ON OUTCHAT  
{
	marray GLOBAL
	marray EXEC
	
	{ title =
	title name =
		{ "$1" GREPSUB name = } name "(.*)[.](.*)" GREPSTR IF
		{ MIDISTOP		;if Midi on a PC
		title SOUND
;if an old client use MIDIPLAY in case it is a midi on a PC.
			{ title MIDIPLAY } IPTVERSION NOT IF
		"" CHATSTR =
		} CHATSTR name == IF
	} musicarray FOREACH

	{ MIDISTOP			;if Midi on a PC
 	"" CHATSTR =
 	} CHATSTR "ms" == IF
}