;Alan's Scrolling Picture script #4
:Moves a picture across the room once.
;Put the same picture in the spot multiple (e.g., 10) times.
;Add this script and customize the information between the lines of asterisks.
;Then say "setpictures <spotnumber>" to automatically set the picture locations.
;Note, you must be an owner/operator to do this.
;Say "reset <spotnumber>" to set the spot to the first picture.
ON ENTER
{
	nbrpics GLOBAL
;***Set the number of pictures***
	15 nbrpics =
;***end of data***
	0 ME SETSPOTSTATELOCAL
}
ON OUTCHAT
{
	nbrpics GLOBAL
	{
		{
;*************************************************
;Set the picture parameters.
;Start and stop positions are relative to the door.
;You must be an Owner/Operator for the script to work.
		0 start_x =
		-50 start_y =
		0 stop_x =
		0 stop_y =
;*************************************************
		nbrpics 1 - steps =
		stop_x start_x - range_x =
		stop_y start_y - range_y =
;
;Move the pictures.  Multiply before divide to reduce error!
;
		0 i =
			{ i ME SETSPOTSTATE
			start_x range_x i * steps / + start_y range_y i * steps / + ME SETPICLOC
			i ++
			} { i nbrpics 1 - <= } WHILE
		0 ME SETSPOTSTATE
		0 inout =
		"" CHATSTR =
		} "$1" GREPSUB ATOI ME == IF
	} CHATSTR "^setpictures ([0-9]+)" GREPSTR IF
;
	{
		{ 0 ME SETSPOTSTATE
		0 inout =	
		"" CHATSTR =
		} "$1" GREPSUB ATOI ME == IF
	} CHATSTR "^reset ([0-9]+)" GREPSTR IF
}
ON SELECT
{
	0 ME SETSPOTSTATELOCAL
	0 ME SETALARM
}
ON ALARM
{
	nbrpics GLOBAL

	ME GETSPOTSTATE 1 + newstate =
	newstate ME SETSPOTSTATELOCAL ;cycle up
		{ 30 ME SETALARM } newstate nbrpics 1 - < IF
}