;Alan's room tour script.
;Place this script in the room from which you want to start the tour.
;Automatically sends you through rooms to be toured.
ON ENTER
{
	ontour GLOBAL
	{ "You have completed the tour.  We hope you enjoyed it.  ;-)" LOCALMSG
	0 ontour =
	} ontour IF
}
ON SELECT
{
	ontour GLOBAL
	roomtour GLOBAL
	{ t_startroom GLOBAL
	t_roomindex GLOBAL
	[
;***list the tour room numbers in the format: 123 456 789 ***
	96
;***End of list***
	] t_roomarray =
	} roomtour DEF
;
	1 ontour =
	roomtour EXEC
	ROOMID t_startroom =
	0 t_roomindex =
	"Welcome to our ... tour." LOCALMSG
	" You will remain in each room long enough to download it and read some messages.
You will then be taken to the next room." LOCALMSG
	"To stop the tour at any time say 'stop' and you will return to this room." LOCALMSG
	"So sit back and enjoy our tour.  ;-)" LOCALMSG
	{ roomtour GLOBAL roomtour EXEC
	t_roomarray 0 GET GOTOROOM } 1800 ALARMEXEC
}





;Alan's tour script
;Put this script in every tour room:
;Optional - place a 'tour guide' as the second picture in this spot.
ON ENTER
{
	ontour GLOBAL
	0 ME SETSPOTSTATELOCAL
	{	"Welcome to " ROOMNAME & "." & LOCALMSG
	"I will provide you with information about this room after you have had time to download the room picture." LOCALMSG
;***Set the time to wait for the room picture to download***
	30 seconds =
;***End of download time***
	seconds 60 * ME SETALARM
	} ontour IF
}
ON OUTCHAT
{
	ontour GLOBAL
	{ t_startroom GLOBAL
	0 ontour =
	"" CHATSTR =
	t_startroom GOTOROOM
	} CHATSTR "stop" == 
	  ontour AND IF
}
ON ALARM
{
;
;go to the next room
;
	{ roomtour GLOBAL roomtour EXEC
	t_roomindex ++
		{ t_startroom GOTOROOM } { t_roomarray t_roomindex GET GOTOROOM
		} t_roomindex t_roomarray LENGTH >= IFELSE
	} ME GETSPOTSTATE IF
;
;show the tour guide and give information
;
	{ 1 ME SETSPOTSTATELOCAL
;***Add the tour message you want, and the time after the message starts until the person is taken to the next room***
	"@300 300 This is the information about this room." LOCALMSG
	30 seconds =
;***End of data****
	seconds 60 * ME SETALARM
	} ME GETSPOTSTATE NOT IF
}