;Alan's password protection script.
;Place this script in an access room:
ON ENTER
{
	rejected GLOBAL
	pwarray GLOBAL
	[
;*****enter each room number and password here in form [ 100 "password_for_room_100" ]
	[ 147 "password147" ]
	[ 148 "password148" ]
;*****end of passwords
	] pwarray =
	{ "You must enter the password for that room to gain access." LOCALMSG
	0 rejected =
	} rejected IF
}
ON OUTCHAT
{
	pwarray GLOBAL
	{ temparray =
		{ "" CHATSTR =
		"pw" temparray 0 GET ITOA & pw =
		pw STRTOATOM EXEC GLOBAL
		1 pw STRTOATOM EXEC =
		temparray 0 GET GOTOROOM
		} CHATSTR temparray 1 GET == IF
	} pwarray FOREACH
}


;Place the following script in each password protected room.
ON ENTER
{
	rejected GLOBAL
;*****************************************************
;set where to send people if they haven't said the password
	86 accessroom =
;*****************************************************
	"pw" ROOMID ITOA & pw =
	pw STRTOATOM EXEC GLOBAL
	{ "You have been given access to this room." LOCALMSG
	} { "'page I attempted entry into " ROOMNAME & "." & SAY
	1 rejected =
	accessroom GOTOROOM
	} pw STRTOATOM EXEC
	  ISWIZARD OR IFELSE
}