;Alan's Move Picture in Path script
;Set the parameters where specified.
;Place the following script in a spot:
ON ENTER
{
	index GLOBAL 0 index =
	0 ME SETSPOTSTATELOCAL
	300 ME SETALARM
;
	patharray GLOBAL
	[
;***Set path parameters***
[ 200 275 ]
[ 220 249 ]
[ 238 223 ]
[ 249 197 ]
[ 262 168 ]
[ 271 138 ]
[ 309 115 ]
[ 353 90 ]
[ 395 62 ]
[ 437 30 ]
[ 475 1 ]
[ 512 0 ]
;***End of data***
	] patharray =
}

ON OUTCHAT
{
;***Set spot x,y***
	197 xspot =
	296 yspot =
;***End of data***
;position the targets
	patharray GLOBAL
	{
		{ 0 i =
			{ i ME SETSPOTSTATE
  			"Setting picture: " i ITOA & LOGMSG
			patharray i GET temparray =
			temparray 0 GET xspot - temparray 1 GET yspot - ME SETPICLOC
			i ++
			} { i patharray LENGTH < } WHILE
		0 ME SETSPOTSTATE
		"" CHATSTR =
		} "$1" GREPSUB ATOI ME == IF
	} CHATSTR "^setpictures ([0-9]+)" GREPSTR
	  ISWIZARD AND IF
}

ON ALARM
{
	index GLOBAL
	patharray GLOBAL
;***Set parameters here***
	60 dt =				;delay time between moves.  Each multiple of 60 is one second.
;*** end of parameters ***
	index ME SETSPOTSTATELOCAL
;first position
	{ } index 0 == IF
;last position
	{
		{ 348 GOTOROOM } dt ALARMEXEC
	} index patharray LENGTH 1 - == IF
;every time
	{ index ++
	dt ME SETALARM
	} index patharray LENGTH 1 - < IF
}