;Alan's looping sound script
ON ENTER
{
	0 ME SETALARM
}
ON ALARM
{
;*************************************************************
;Enter the name of your sound file in quotes:
	"waterfall" soundfile =
;Specify the time it takes to play your sound in minutes, seconds
;and 10ths of seconds.
;Adjust the time until the sound starts again just after it stops each time.
;A long pause means it is trying to start too soon.
	0 minutes =
	33 seconds =
	8 tenthsofseconds =
;*************************************************************
	MIDISTOP
	soundfile SOUND
;if an old client use MIDIPLAY in case it is a midi on a PC.
		{ soundfile MIDIPLAY } IPTVERSION NOT IF
	minutes 3600 * seconds 60 * + tenthsofseconds 6 * + ME SETALARM
}



;Alan's looping sound with on/off control
;modified from a script by unknown author
ON ENTER
{
	snd GLOBAL
	1 snd =
	"Say 'on' or 'off' to control the music." STATUSMSG
	1 ME SETALARM
}
ON OUTCHAT
{
	snd GLOBAL
	{ 1 snd =
	1 ME SETALARM
	"" CHATSTR =
	} snd NOT
	  CHATSTR "on" == AND IF
	{ 0 snd =
	"" CHATSTR =
	} CHATSTR "off" == IF
}
ON ALARM
{
	snd GLOBAL
;*************************************************************
;Enter the name of your sound file in quotes:
	"tobeloved_m" soundfile =
;Specify the time it takes to play your sound in minutes, seconds
;and 10ths of seconds.
;Adjust the time until the sound starts again just after it stops each time.
;A long pause means it is trying to start too soon.
	4 minutes =
	55 seconds =
	0 tenthsofseconds =
;*************************************************************
	{ MIDISTOP
	soundfile SOUND
;if an old client use MIDIPLAY in case it is a midi on a PC.
		{ soundfile MIDIPLAY } IPTVERSION NOT IF
	minutes 3600 * seconds 60 * + tenthsofseconds 6 * + ME SETALARM
	} snd IF
}