;Alan's controllable animation script
; - Animate upon room entry or when command entered.
; - Animate once or continuously.
ON ENTER 
{
	animate GLOBAL
	loop GLOBAL
	manual GLOBAL
	startcmd GLOBAL
	stopcmd GLOBAL
;
;***Setup Parameters***
	1 loop =						;0 to loop once, 1 to loop continuously
	1 manual =						;0 to start on entry, 1 to make user start
	"start animation" startcmd =	;command to start animation
	"stop animation" stopcmd =		;command to stop animation
;***End of Setup Parameters***
;
	1 animate =
	{ "Say '" startcmd & "' to start the animation." & LOCALMSG
	"Say '" stopcmd & "' to stop the animation." & LOCALMSG
	} { 0 ME SETALARM } manual IFELSE
}

ON OUTCHAT
{
	animate GLOBAL
	manual GLOBAL
	startcmd GLOBAL
	stopcmd GLOBAL

;start/stop animation
	{ 1 animate =
	0 ME SETALARM
	"" CHATSTR =
	} CHATSTR startcmd ==
	  manual AND IF
;
	{ 0 animate =
	"" CHATSTR =
	} CHATSTR stopcmd ==
	  manual AND IF
}

ON ALARM 
{
	animate GLOBAL
	loop GLOBAL
;
;***Setup Parameters****
	6 nbrpictures =		;number of pictures in this spot
	60 dtime =	;time each picture is displayed.
						;Each multiple of 60 is one second of display.
;***End of Setup Parameters***
;
	{ ME GETSPOTSTATE 1 + nbrpictures % ME SETSPOTSTATELOCAL
	dtime ME SETALARM
	} loop NOT
	  ME GETSPOTSTATE nbrpictures 1 - == NOT AND
	  loop OR
	  animation AND IF
}