;Place this entire script in your gate.
;In addition, place the last portion of this script, only, in rooms where you want this function.
ON SIGNON
{
;Allscray - cause others in room to say/do things.  Does not affect other Owners/Operators.
;If you whisper to someone they are the only one affected.
; ";as" makes everyone say/do something
; ";ao" makes everyone except you say/do something.
;This is an INCHAT script
	xDoIt GLOBAL
	nDoIt GLOBAL
; let anybody use Allscary - NOT RECOMMENDED.
	{
		{ "$1" GREPSUB STRTOATOM EXEC } CHATSTR LOWERCASE "^;as (.*)" GREPSTR
		                                ISWIZARD NOT AND IF
		{ "$1" GREPSUB STRTOATOM EXEC } CHATSTR LOWERCASE "^;ao (.*)" GREPSTR
		                                WHOCHAT WHOME == NOT AND
		                                ISWIZARD NOT AND IF
		{ "$1" GREPSUB STRTOATOM EXEC } CHATSTR LOWERCASE "^;*allscray (.*)" GREPSTR IF

;myavis - receive the cloned av
		{ "$1 SETPROPS" GREPSUB STRTOATOM EXEC
		"Received cloned prop." LOGMSG
		} CHATSTR LOWERCASE "^;myavis (.*)$" GREPSTR
	 	 WHOCHAT WHOTARGET == AND IF
	} xDoIt DEF

; let only Owners and Operators use Allscray.  They must be wearing their *.
	{ xDoIt GLOBAL
		{ xDoIt EXEC } WHOCHAT WHONAME "^[*]" GREPSTR IF
	} nDoIt DEF


;Allscraycommands - useful allscray commands
;Uses Owners/Operators, only, allscray.
;This is an OUTCHAT script
	allscraycommands GLOBAL
	{
;gothere - send to mouse position
		{ ";ao " MOUSEPOS SWAP ITOA " " & SWAP ITOA & & " SETPOS" & CHATSTR =
		} CHATSTR "gothere" == IF

;sendroom - send to another room
		{ ";ao $1 GOTOROOM" GREPSUB CHATSTR =
		} CHATSTR LOWERCASE "sendroom ([0-9]*)" GREPSTR IF

;sendpal - send to another palace
		{ ";ao \"palace://$1\" NETGOTO" GREPSUB CHATSTR =
		} CHATSTR LOWERCASE "sendpal (.*)" GREPSTR IF

;sendweb - send to a web address
		{ ";ao \"http://$1\" NETGOTO" GREPSUB CHATSTR =
		} CHATSTR LOWERCASE "sendweb (.*)" GREPSTR IF

;ghost - see if the person has poofed
		{ ";ao \"I'm still here.\" WHOCHAT PRIVATEMSG" CHATSTR =
		} CHATSTR "ghost" == IF

;clone - clone the avatar of another person.
		{
			{ ";ao 
			0 i =
			\"i: \" i ITOA & LOGMSG
				{ \";myavis [ \"
					{  i USERPROP ITOA & \" \" &
					i ++
					} { i NBRUSERPROPS < } WHILE \"]\" & WHOCHAT PRIVATEMSG
				} NBRUSERPROPS IF" WHOTARGET PRIVATEMSG
			} { "Clone:  You must be whispering to someone." LOGMSG } WHOTARGET IFELSE
		"" CHATSTR =
		} CHATSTR "clone" == IF

;giveav - give your av to other(s)
		{ ";allscray [ " p =
		0 i =
			{ p i USERPROP ITOA & " " & p =
			i ++
			} { i NBRUSERPROPS < } WHILE
		p "] SETPROPS" & CHATSTR =
		} CHATSTR "giveav" == IF
	} allscraycommands DEF
}



;The following is part of the this gate script.
;In addition, place the following section, only, in rooms where you want this function.
;Enable gate functions.
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON OUTCHAT { allscraycommands GLOBAL allscraycommands EXEC }